Disclaimer
This is a custom PKGBUILD.
To educate yourself on use of AUR and why it is unsupported please jump to article About Manjaro and AUR
This is only valid for dotnet core 6.
The reason I choose to maintain it myself, is because the work I do with dotnet core is quickly rolled into production, making it important to stay up-to-date on security and bug-fixes.
I assume you are familiar with the manual build process and you have base-devel synced to your system.
Initially you clone the custom PKGBUILD named dotnet-core-bin from AUR. You will find besides the PKGBUILD, a dotnet.sh which is used for important installation tasks.
git clone https://aur.archlinux.org/dotnet-core-bin.git
The script is a split package script and thus creating 7 packages to install on your system. The work I do requires all packages so I install everything
[dotnet-core-bin] $ makepkg -is
I have restructured my PKGBUILD - added comments so I remember what to maintain - in case you wonder why it doesn’t look like the original 
You need the info provided on Download .NET 6.0 (Linux, macOS, and Windows) and you also need the direct link and checksum when you click download on the relevant architecture
Paste the link(s) into the relevant source_* variable in the PKGBUILD.
You can do the same with the checksums - and when doing so you can skip the updpkgsums command and got straight to building/installing the packages
makepkg -is
If it is fairly mundane task to accomplish, really - as you only have to modify the elements which is valid for your architecture.
[...]
# maintenance section
# necessary info is obtained at https://dotnet.microsoft.com/en-us/download/dotnet/6.0
pkgver=6.0.14.sdk406
_runtimever=6.0.14
_sdkver=6.0.406
pkgrel=1
# direct link is obtained by clicking the relevant architecture (cancel download and copy the link for the relevant architecture)
#source_armv7h=('https://download.visualstudio.microsoft.com/download/pr/f35557f7-d5e1-43be-93b6-e59ee8bd823c/9dd2c25a4d7351412ff5902c355732ca/dotnet-sdk-6.0.302-linux-arm.tar.gz')
#source_aarch64=('https://download.visualstudio.microsoft.com/download/pr/33389348-a7d7-41ae-850f-ec46d3ca9612/36bad11f948b05a4fa9faac93c35e574/dotnet-sdk-6.0.302-linux-arm64.tar.gz')
source_x86_64=('https://download.visualstudio.microsoft.com/download/pr/265a56e6-bb98-4b17-948b-bf9884ee3bb3/e2a2587b9a964d155763b706dffaeb8b/dotnet-sdk-6.0.406-linux-x64.tar.gz')
# checksum is on the same page as the direct download link (copy and paste for the relevant architecture)
#sha512sums_armv7h=('0d31c7e8ccf02c8dea92d7b60bcb15e15912d74e7ee2ab8fd88ee03c4fbd8f292c356357d08ec23c2aedc5e3e0803d42ce16f3fff36245739d0cac6634bc3387')
#sha512sums_aarch64=('26e98a63665d707b1a7729f1794077316f9927edd88d12d82d0357fe597096b0d89b64a085fcdf0cf49807a443bbfebb48e10ea91cea890846cf4308e67c4ea5')
sha512sums_x86_64=('4553aed8455501e506ee7498a07bff56e434249406266f9fd50eb653743e8fc9c032798f75e34c2a2a2c134ce87a8f05a0288fc8f53ddc1d7a91826c36899692')
# maintenance section end
[...]
My complete PKGBUILD for reference
git clone https://codeberg.org/wonky/dotnet-core-bin-sdk6.git
# Maintainer : Frede Hundewadt <https://codeberg.org/wonky>
# Contributor: Attila Greguss <floyd0122[at]gmail[dot]com>
# maintenance section
# necessary info is obtained at https://dotnet.microsoft.com/en-us/download/dotnet/6.0
pkgver=6.0.14.sdk406
_runtimever=6.0.14
_sdkver=6.0.406
pkgrel=1
# direct link is obtained by clicking the relevant architecture (cancel download and copy the link for the relevant architecture)
#source_armv7h=('https://download.visualstudio.microsoft.com/download/pr/f35557f7-d5e1-43be-93b6-e59ee8bd823c/9dd2c25a4d7351412ff5902c355732ca/dotnet-sdk-6.0.302-linux-arm.tar.gz')
#source_aarch64=('https://download.visualstudio.microsoft.com/download/pr/33389348-a7d7-41ae-850f-ec46d3ca9612/36bad11f948b05a4fa9faac93c35e574/dotnet-sdk-6.0.302-linux-arm64.tar.gz')
source_x86_64=('https://download.visualstudio.microsoft.com/download/pr/265a56e6-bb98-4b17-948b-bf9884ee3bb3/e2a2587b9a964d155763b706dffaeb8b/dotnet-sdk-6.0.406-linux-x64.tar.gz')
# checksum is on the same page as the direct download link (copy and paste for the relevant architecture)
#sha512sums_armv7h=('0d31c7e8ccf02c8dea92d7b60bcb15e15912d74e7ee2ab8fd88ee03c4fbd8f292c356357d08ec23c2aedc5e3e0803d42ce16f3fff36245739d0cac6634bc3387')
#sha512sums_aarch64=('26e98a63665d707b1a7729f1794077316f9927edd88d12d82d0357fe597096b0d89b64a085fcdf0cf49807a443bbfebb48e10ea91cea890846cf4308e67c4ea5')
sha512sums_x86_64=('4553aed8455501e506ee7498a07bff56e434249406266f9fd50eb653743e8fc9c032798f75e34c2a2a2c134ce87a8f05a0288fc8f53ddc1d7a91826c36899692')
# maintenance section end
# packaging
pkgbase=dotnet-core-bin
pkgname=(
'dotnet-host-bin'
'aspnet-runtime-bin'
'dotnet-runtime-bin'
'dotnet-sdk-bin'
'netstandard-targeting-pack-bin'
'dotnet-targeting-pack-bin'
'aspnet-targeting-pack-bin'
)
arch=('x86_64' 'armv7h' 'aarch64')
url='https://www.microsoft.com/net/core'
license=('MIT')
options=('staticlibs')
source=('dotnet.sh')
sha512sums=('e61b9e3e5a2305646a616d598378230c9755c5dd5363692cc363f8f4add3807563c324dd86f3a7ae9d358c82d730608e7b293935a2b6c81c0c0f62d752a0a1cf')
package_dotnet-host-bin() {
pkgdesc='A generic driver for the .NET Core Command Line Interface (binary)'
provides=("dotnet-host" "dotnet-host=${_runtimever}")
depends=(
'gcc-libs'
'glibc'
)
conflicts=('dotnet-host')
install -dm 755 "${pkgdir}"/usr/{bin,lib,share/{dotnet,licenses/dotnet-host}}
cp -dr --no-preserve='ownership' dotnet host "${pkgdir}"/usr/share/dotnet/
cp -dr --no-preserve='ownership' LICENSE.txt ThirdPartyNotices.txt "${pkgdir}"/usr/share/licenses/dotnet-host
ln -sf /usr/share/dotnet/dotnet "${pkgdir}"/usr/bin/dotnet
ln -sf /usr/share/dotnet/host/fxr/"${_runtimever}"/libhostfxr.so "${pkgdir}"/usr/lib/libhostfxr.so
install -Dm 644 "${srcdir}"/dotnet.sh -t "${pkgdir}"/etc/profile.d/
}
package_dotnet-runtime-bin() {
pkgdesc='The .NET Core runtime (binary)'
depends=(
"dotnet-host>=${_runtimever}"
'gcc-libs'
'glibc'
'icu'
'libgssapi_krb5.so'
'libunwind'
'zlib'
'openssl'
)
optdepends=('lttng-ust: CoreCLR tracing')
provides=("dotnet-runtime=${_runtimever}" "dotnet-runtime-6.0")
conflicts=("dotnet-runtime=${_runtimever}" "dotnet-runtime-6.0")
install -dm 755 "${pkgdir}"/usr/share/{dotnet/shared,licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.NETCore.App "${pkgdir}"/usr/share/dotnet/shared/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-runtime-bin
}
package_aspnet-runtime-bin() {
pkgdesc='The ASP.NET Core runtime (binary)'
depends=('dotnet-runtime-bin')
provides=("aspnet-runtime=${_runtimever}" "aspnet-runtime-6.0")
conflicts=("aspnet-runtime=${_runtimever}" "aspnet-runtime-6.0")
install -dm 755 "${pkgdir}"/usr/share/{dotnet/shared,licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.AspNetCore.App "${pkgdir}"/usr/share/dotnet/shared/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/aspnet-runtime-bin
}
package_dotnet-sdk-bin() {
pkgdesc='The .NET Core SDK (binary)'
depends=(
'glibc'
'gcc-libs'
'dotnet-runtime-bin'
'dotnet-targeting-pack-bin'
'netstandard-targeting-pack-bin')
optdepends=('aspnet-targeting-pack-bin: Build ASP.NET Core applications')
provides=("dotnet-sdk-bin" "dotnet-sdk=${pkgver}" "dotnet-sdk-6.0")
conflicts=("dotnet-sdk-bin" "dotnet-sdk=${pkgver}" "dotnet-sdk-6.0")
install -dm 755 "${pkgdir}"/usr/share/{dotnet,licenses}
cp -dr --no-preserve='ownership' sdk sdk-manifests templates "${pkgdir}"/usr/share/dotnet/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-sdk-bin
}
package_netstandard-targeting-pack-bin() {
pkgdesc='The .NET Standard targeting pack (binary)'
provides=('netstandard-targeting-pack-2.1' 'netstandard-targeting-pack')
conflicts=('netstandard-targeting-pack-2.1' 'netstandard-targeting-pack')
install -dm 755 "${pkgdir}"/usr/share/{dotnet,dotnet/packs,licenses}
cp -dr --no-preserve='ownership' packs/NETStandard.Library.Ref "${pkgdir}"/usr/share/dotnet/packs/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/netstandard-targeting-pack
}
package_dotnet-targeting-pack-bin() {
pkgdesc='The .NET Core targeting pack (binary)'
depends=(netstandard-targeting-pack-bin)
provides=(dotnet-targeting-pack=${_runtimever} dotnet-targeting-pack-6.0)
conflicts=(dotnet-targeting-pack=${_runtimever} dotnet-targeting-pack-6.0)
if [ $CARCH = 'x86_64' ]; then msarch=x64;
elif [ $CARCH = 'armv7h' ]; then msarch=arm;
elif [ $CARCH = 'aarch64' ]; then msarch=arm64; fi
install -dm 755 "${pkgdir}"/usr/share/{dotnet,dotnet/packs,licenses}
cp -dr --no-preserve='ownership' packs/Microsoft.NETCore.App.{Host.linux-${msarch},Ref} "${pkgdir}"/usr/share/dotnet/packs/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-targeting-pack-bin
}
package_aspnet-targeting-pack-bin() {
pkgdesc='The ASP.NET Core targeting pack (binary)'
depends=(dotnet-targeting-pack-bin)
provides=(aspnet-targeting-pack=${_runtimever} aspnet-targeting-pack-6.0)
conflicts=(aspnet-targeting-pack=${_runtimever} aspnet-targeting-pack-6.0)
install -dm 755 "${pkgdir}"/usr/share/{dotnet,dotnet/packs,licenses}
cp -dr --no-preserve='ownership' packs/Microsoft.AspNetCore.App.Ref "${pkgdir}"/usr/share/dotnet/packs/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/aspnet-targeting-pack-bin
}
