Paper-Maia-Icon-Theme : A Manjaro variation of the Paper-icon-theme

Hi Community!

Creating a Manjaro(maia) variation of the simple and modern paper icon theme and so far it went good. Here is a screenshot:-

You can find PKGBUILD here.

11 Likes

I have a rough version cobbled together from an old incomplete version of Paper with Papirus as the fallback. This used a bunsenlabs colour-changing script but didn’t seem to work on newer versions of Paper (probably because files/folders/symlinks have been renamed or added to).

So it would be great if your version is based on a much more complete Paper set. Off to download it now! :sunglasses:

Tested it. Nice!

The notification area icons are more consistent in size and look - I’m guessing you are using Papirus-style notification area icons - so that’s a plus. In comparison, my volume slider icon from Paper was a large grey speaker.

Your Paper version is definitely more complete than the version I’m using.

On the other hand, in your version the icon assigned to Octopi (which my version did not have) is a “brown parcel” graphic for a generic package manager. I think that is less interesting than the octopus/videogame pacman icon . But that’s subjective.

Ultimately though, the introduction of a maia version of Paper icon set is highly welcomed and appreciated.

Very nice variation. Nice incorporation. :smiley:

regards

@vaibhav nice work, can be exist with regular paper icon theme ? Can be installed without conflicts with the regular ?
I want merge in Manjaro :grin:

2 Likes

Hi @Ste74, yes it can work with the regular paper icon theme and can be installed without any conflicts with regular one. Moreover, it needs “paper-icon-theme-git” package as a dependency. I wrote a PKGBUILD for building it. It is ready for the merge (if you wish).

@wongs
@c00ter
@Ste74
Thanks for the appreciation.

4 Likes

The BitBucket repo is gone. :frowning_face:

Sorry for deplay. Currently too busy for updating the repo.

Just pushed some changes and fixed the broken URL. Now @Yochanan can access the repo(just see my initial post).

1 Like

I tweaked the PKGBUILD a bit:

PKGBUILD
# Maintainer: Vaibhav Singh <vaibhavlinux at bitbucket dot org>
pkgname=paper-maia-icon-theme-git
pkgver=746.04115106
pkgrel=4
pkgdesc="Manjaro variation of Paper Icon Theme"
arch=('any')
url="https://bitbucket.org/vaibhavlinux/paper-maia-icon-theme-git"
license=('CC BY-SA 4.0')
depends=('paper-icon-theme-git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://bitbucket.org/vaibhavlinux/$pkgname.git#tag=4d753f51a2d5")
sha256sums=('SKIP')

package() {
	cd "$srcdir/$pkgname"
	install -d "$pkgdir/usr/share/icons"
	cp -r Paper-Maia "$pkgdir/usr/share/icons/"
	cp -r Paper-Maia-Mono-Dark "$pkgdir/usr/share/icons/"
	ln -s /usr/share/icons/Paper-Mono-Dark/22x22 \
		"$pkgdir/usr/share/icons/Paper-Maia-Mono-Dark"
	ln -s /usr/share/icons/Paper-Mono-Dark/24x24 \
		"$pkgdir/usr/share/icons/Paper-Maia-Mono-Dark"
}

Really the repo should not contain the -git suffix. That's only for the package itself.

Since paper-icon-theme-git depends on gtk-update-icon-cache, you don't need to list it as a dependency since it's already covered.

Try and avoid unnecessary variables if you can help it. :wink:

Moved from #showcase to #manjaro-development:projects since it's a project created for Manjaro users. Also so it doesn't get lost amongst all the desktop screenshots & wallpapers

1 Like

Just added that to my notes. Very thanks.

I will soon update it with your amendments and notify here. Moreover I may do this to all my PKGBUILDs.

You are the real expert!

Done!

PKGBUILD(decluttered)
# Maintainer: Vaibhav Singh <vaibhavlinux at bitbucket dot org>

pkgname=paper-maia-icon-theme-git
pkgver=746.04115106
pkgrel=4
pkgdesc="Manjaro variation of Paper Icon Theme"
arch=('any')
url="https://bitbucket.org/vaibhavlinux/paper-maia-icon-theme"
license=('CC BY-SA 4.0')
depends=('paper-icon-theme-git')
makedepends=('git')
source=("git+$url.git")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
    cd "$srcdir/$pkgname"
    install -d "$pkgdir/usr/share/icons"
    cp -r Paper-Maia "$pkgdir/usr/share/icons/"
    cp -r Paper-Maia-Mono-Dark "$pkgdir/usr/share/icons/"
    ln -s /usr/share/icons/Paper-Mono-Dark/22x22 \
            "$pkgdir/usr/share/icons/Paper-Maia-Mono-Dark"
    ln -s /usr/share/icons/Paper-Mono-Dark/24x24 \
            "$pkgdir/usr/share/icons/Paper-Maia-Mono-Dark"
}

Since you removed the tag and are no longer building a static version, you need to add a pkgver() array:

pkgver() {
	cd "$srcdir/$pkgname"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

That creates pkgver=r8.4d753f5

2 Likes

Very thanks! I am really getting to learn new things, please can you explain that git part in your code, just want too know more about how it works.

Also added VCS to makedepends() array with the push.

See VCS package guidelines: Git

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.

Forum kindly sponsored by